14 sample_ezfrm.hsp

sample\ 14 sample_ezfrm.hsp

#include "mod_layerbutton.hsp"
#include "mod_layerbutton-emes.hsp"

log = ""
// 左側ボタン作成
pos 50, 20
repeat 3
	pos ,ginfo_cy+10
	bt_opt += 10
	layerbutton 180,60, bt_opt, 0, 30,10,5, 15,5,2 {
		if lparam != objlayer_cmddraw : return  ; _cmddraw以外無視
		font msgothic,16,1 : color 40,40,200 : objcolor 200,200,255  ; 文字色 / 縁取り色
		laybtn_ezfrm $A0A0A0, $000000, $FF0000, 3,"frmボタン "+objlayer_option
		if layerbtn_stat != LAYBTN_COMPLETE_SELECTED : return  ; 押したボタン以外無視
		log += "LAYBTN_COMPLETE_SELECTED" +"\n"
		log += "- OPT="+objlayer_option+", ObjID="+wparam +"\n"
		return
	}
loop
// 右側ボタン作成
pos 300, 40
repeat 3
	pos ,ginfo_cy+10
	bt_opt += 20
	layerbutton 180,60, bt_opt, 1, 30,10,5, 15,5,2 {
		if lparam != objlayer_cmddraw : return  ; _cmddraw以外無視
		font msgothic,16,1 : color 240,240,255 : objcolor 0,0,100  ; 文字色 / 縁取り色
		laybtn_ezbox $AA9999FF, $AA0000FF, $AA3333AA, "box+frmボタン "+objlayer_option,4
		laybtn_ezfrm $99FFFFFF, $99FFFFFF, $99FFFFFF, 1,,,,,,,,,,-3,-3
		if layerbtn_stat != LAYBTN_COMPLETE_SELECTED : return  ; 押したボタン以外無視
		log += "LAYBTN_COMPLETE_SELECTED" +"\n"
		log += "- OPT="+objlayer_option+", ObjID="+wparam +"\n"
		return
	}
loop
// 下部メッセージボックス作成
pos 70,330 : color 255,255,255
story_text={"
某RPG風ウィンドウメッセージ^
*「よくぞ参った、勇者よ……。~
\　 この国は今、闇に覆われておる。~そなたの力を
\　 貸してほしい。
"}
layeremes 500,120, 1000, 2, story_text,0, 4 {
	layemes_font msgothic, 19, 1
	layemes_settings 0,0,5
	if lparam == objlayer_cmddraw {
		laybtn_ezbox $FF313021,,,,,,,,,10,,,40,20  ; オブジェクトの範囲をはみ出して枠を描画
		laybtn_ezfrm $EEFFFFFF, $EEFFFFFF, $EEFFFFFF, 4,,,,,,,10,,,38,18
	}
	if lparam == objlayer_cmdterm {
		log += "LAYEMES_cmdterm" +"\n"
		log += "- OPT="+objlayer_option+", ObjID="+wparam +"\n"
	}
	return
}

// 表示メインループ
repeat
	redraw 0 : color 245,245,245 : boxf : color : pos 0,0 : font msgothic,16
	mes log
	redraw 1
	await 1000/60
loop